1:  ∫((A+B Log[c (((d+e x))^n)])/(Sqrt[a+b Log[c (((d+e x))^n)]]))dx

Rule:

∫((A+B Log[c (((d+e x))^n)])/(Sqrt[a+b Log[c (((d+e x))^n)]]))dx  ⟶  
((B (d+e x) (Sqrt[a+b Log[c (((d+e x))^n)]]))/(b e))+((2 A b-B (2 a+b n))/(2 b)) ∫(1/(Sqrt[a+b Log[c (((d+e x))^n)]]))dx

Program code:

Int[(A_.+B_.*Log[c_.*(d_.+e_.*x_)^n_.])/Sqrt[a_+b_.*Log[c_.*(d_.+e_.*x_)^n_.]],x_Symbol] :=
  B*(d+e*x)*Sqrt[a+b*Log[c*(d+e*x)^n]]/(b*e) + 
  (2*A*b-B*(2*a+b*n))/(2*b)*Int[1/Sqrt[a+b*Log[c*(d+e*x)^n]],x] /;
FreeQ[{a,b,c,d,e,A,B,n},x]

Rules for integrands of the form  u (((a+b Log[c (x^n)]))^p)

4.  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

0:  ∫(x^m) (((d+(e/x)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==q ∧ q∈ℤ

Derivation: Algebraic simplification

Rule: If  m==q ∧ q∈ℤ, then

∫(x^m) (((d+(e/x)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((e+d x))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[x_^m_.*(d_+e_./x_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Int[(e+d*x)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p},x] && EqQ[m,q] && IntegerQ[q]

1:  ∫(x^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  q∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Rule: If  q∈(SuperPlus[ℤ])∧ m∈ℤ, let u->∫(x^m) (((d+e (x^r)))^q)dx, then

∫(x^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[x_^m_.*(d_+e_.*x_^r_.)^q_.*Log[c_.*x_^n_.],x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*x^r)^q,x]},
  Dist[Log[c*x^n],u,x] - n*Int[SimplifyIntegrand[u/x,x],x]] /;
FreeQ[{c,d,e,n,r},x] && IGtQ[q,0] && IntegerQ[m] && Not[EqQ[q,1] && EqQ[m,-1]]

Int[x_^m_.*(d_+e_.*x_^r_.)^q_.*(a_+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[x^m*(d+e*x^r)^q,x]},
  u*(a+b*Log[c*x^n]) - b*n*Int[SimplifyIntegrand[u/x,x],x]] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[q,0] && IntegerQ[m] && Not[EqQ[q,1] && EqQ[m,-1]]

2:  ∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  m+r(q+1)+1==0 ∧ m≠-1

Derivation: Integration by parts

Basis: If  m+r(q+1)+1==0 ∧ m≠-1, then (((f x))^m) (((d+e (x^r)))^q)==(∂_x)(((((f x))^(m+1)) (((d+e (x^r)))^(q+1)))/(d f (m+1)))

Rule: If  m+r(q+1)+1==0 ∧ m≠-1, then

∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  (((((f x))^(m+1)) (((d+e (x^r)))^(q+1)) (a+b Log[c (x^n)]))/(d f (m+1)))-((b n)/(d (m+1)))∫(((f x))^m) (((d+e (x^r)))^(q+1))dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  (f*x)^(m+1)*(d+e*x^r)^(q+1)*(a+b*Log[c*x^n])/(d*f*(m+1)) - 
  b*n/(d*(m+1))*Int[(f*x)^m*(d+e*x^r)^(q+1),x] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && EqQ[m+r*(q+1)+1,0] && NeQ[m,-1]

3.  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])

1.  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0)

1:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r==n

Derivation: Integration by substitution

Rule: If  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r==n, then

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ((f^m)/n) Subst[∫(((d+e x))^q) (((a+b Log[c x]))^p)dx,x,(x^n)]

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_)^q_.*(a_.+b_.*Log[c_.*x_^n_])^p_.,x_Symbol] :=
  f^m/n*Subst[Int[(d+e*x)^q*(a+b*Log[c*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && EqQ[m,r-1] && IGtQ[p,0] && (IntegerQ[m] || GtQ[f,0]) && EqQ[r,n]

2.  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n

1:  ∫(((((f x))^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n

Derivation: Integration by parts

Basis: ((((f x))^m)/(d+e (x^r)))==((f^m)/(e r))(∂_x)Log[1+((e (x^r))/d)]

Rule: If  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n, then

∫(((((f x))^m) (((a+b Log[c (x^n)]))^p))/(d+e (x^r)))dx  ⟶  (((f^m) Log[1+((e (x^r))/d)] (((a+b Log[c (x^n)]))^p))/(e r))-((b (f^m) n p)/(e r)) ∫((Log[1+((e (x^r))/d)] (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*Log[c_.*x_^n_.])^p_./(d_+e_.*x_^r_),x_Symbol] :=
  f^m*Log[1+e*x^r/d]*(a+b*Log[c*x^n])^p/(e*r) - 
  b*f^m*n*p/(e*r)*Int[Log[1+e*x^r/d]*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,f,m,n,r},x] && EqQ[m,r-1] && IGtQ[p,0] && (IntegerQ[m] || GtQ[f,0]) && NeQ[r,n]

2:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n ∧ q≠-1

Derivation: Integration by parts

Rule: If  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ (m∈ℤ ∨ f>0) ∧ r≠n ∧ q≠-1, then

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  (((f^m) (((d+e (x^r)))^(q+1)) (((a+b Log[c (x^n)]))^p))/(e r (q+1)))-((b (f^m) n p)/(e r (q+1))) ∫(((((d+e (x^r)))^(q+1)) (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  f^m*(d+e*x^r)^(q+1)*(a+b*Log[c*x^n])^p/(e*r*(q+1)) - 
  b*f^m*n*p/(e*r*(q+1))*Int[(d+e*x^r)^(q+1)*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && EqQ[m,r-1] && IGtQ[p,0] && (IntegerQ[m] || GtQ[f,0]) && NeQ[r,n] && NeQ[q,-1]

2:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ ¬(m∈ℤ ∨ f>0)

Derivation: Piecewise constant extraction

Rule: If  m==r-1 ∧ p∈(SuperPlus[ℤ])∧ ¬(m∈ℤ ∨ f>0), then

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ((((f x))^m)/(x^m)) ∫(x^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(f_*x_)^m_.*(d_+e_.*x_^r_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  (f*x)^m/x^m*Int[x^m*(d+e*x^r)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && EqQ[m,r-1] && IGtQ[p,0] && Not[(IntegerQ[m] || GtQ[f,0])]

4.  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  q+1∈(SuperMinus[ℤ])

1:  ∫(((f x))^m) (((d+e x))^q) (a+b Log[c (x^n)])dx  when  q+1∈(SuperMinus[ℤ])∧ m>0

Rule: If  q+1∈(SuperMinus[ℤ])∧ m>0, then

∫(((f x))^m) (((d+e x))^q) (a+b Log[c (x^n)])dx  ⟶  
(((((f x))^m) (((d+e x))^(q+1)) (a+b Log[c (x^n)]))/(e (q+1)))-(f/(e (q+1)))∫(((f x))^(m-1)) (((d+e x))^(q+1)) (a m+b n+b m Log[c (x^n)])dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  (f*x)^m*(d+e*x)^(q+1)*(a+b*Log[c*x^n])/(e*(q+1)) - 
  f/(e*(q+1))*Int[(f*x)^(m-1)*(d+e*x)^(q+1)*(a*m+b*n+b*m*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && ILtQ[q,-1] && GtQ[m,0]

2:  ∫(((f x))^m) (((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  when  q+1∈(SuperMinus[ℤ])∧ m∈(SuperMinus[ℤ])

Rule: If  q+1∈(SuperMinus[ℤ])∧ m∈(SuperMinus[ℤ]), then

∫(((f x))^m) (((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  ⟶  
-(((((f x))^(m+1)) (((d+e (x^2)))^(q+1)) (a+b Log[c (x^n)]))/(2 d f (q+1)))+(1/(2 d (q+1)))∫(((f x))^m) (((d+e (x^2)))^(q+1)) (a (m+2 q+3)+b n+b (m+2 q+3) Log[c (x^n)])dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^2)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  -(f*x)^(m+1)*(d+e*x^2)^(q+1)*(a+b*Log[c*x^n])/(2*d*f*(q+1)) + 
  1/(2*d*(q+1))*Int[(f*x)^m*(d+e*x^2)^(q+1)*(a*(m+2*q+3)+b*n+b*(m+2*q+3)*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && ILtQ[q,-1] && ILtQ[m,0]

5:  ∫(x^m) (((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  when  (m/2)∈ℤ ∧ q-(1/2)∈ℤ ∧ ¬(m+2 q<-2 ∨ d>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((d+e (x^2)))^q)/(((1+(e/d) (x^2)))^q))==0

Rule: If (m/2)∈ℤ ∧ q-(1/2)∈ℤ ∧ ¬(m+2 q<-2 ∨ d>0), then

∫(x^m) (((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  ⟶  (((d^(IntPart[q]))(((d+e (x^2)))^(FracPart[q])))/(((1+(e/d) (x^2)))^(FracPart[q]))) ∫(x^m) (((1+(e/d) (x^2)))^q) (a+b Log[c (x^n)])dx

Program code:

Int[x_^m_.*(d_+e_.*x_^2)^q_*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  d^IntPart[q]*(d+e*x^2)^FracPart[q]/(1+e/d*x^2)^FracPart[q]*Int[x^m*(1+e/d*x^2)^q*(a+b*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d,e,n},x] && IntegerQ[m/2] && IntegerQ[q-1/2] && Not[LtQ[m+2*q,-2] || GtQ[d,0]]

Int[x_^m_.*(d1_+e1_.*x_)^q_*(d2_+e2_.*x_)^q_*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  (d1+e1*x)^q*(d2+e2*x)^q/(1+e1*e2/(d1*d2)*x^2)^q*Int[x^m*(1+e1*e2/(d1*d2)*x^2)^q*(a+b*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n},x] && EqQ[d2*e1+d1*e2,0] && IntegerQ[m] && IntegerQ[q-1/2]

6.  ∫(((((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])

1.  ∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  when  p∈(SuperPlus[ℤ])

1:  ∫((a+b Log[c (x^n)])/(x (d+e (x^r))))dx  when  (r/n)∈ℤ

Derivation: Integration by substitution

Basis: ((F[(x^n)])/x)==(1/n) Subst[((F[x])/x),x,(x^n)] (∂_x)(x^n)

Rule: If (r/n)∈ℤ, then

∫((a+b Log[c (x^n)])/(x (d+e (x^r))))dx  ⟶  (1/n) Subst[∫((a+b Log[c x])/(x (d+e (x^(r/n)))))dx,x,(x^n)]

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_])/(x_*(d_+e_.*x_^r_.)),x_Symbol] :=
  1/n*Subst[Int[(a+b*Log[c*x])/(x*(d+e*x^(r/n))),x],x,x^n] /;
FreeQ[{a,b,c,d,e,n,r},x] && IntegerQ[r/n]

2:  ∫((((a+b Log[c (x^n)]))^p)/(x (d+e x)))dx  when  p∈(SuperPlus[ℤ])

Rule: Algebraic expansion

Basis: (1/(x (d+e x)))==(1/(d x))-(e/(d (d+e x)))

Rule: If  p∈(SuperPlus[ℤ]), then

∫((((a+b Log[c (x^n)]))^p)/(x (d+e x)))dx  ⟶  (1/d)∫((((a+b Log[c (x^n)]))^p)/x)dx-(e/d)∫((((a+b Log[c (x^n)]))^p)/(d+e x))dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_./(x_*(d_+e_.*x_)),x_Symbol] :=
  1/d*Int[(a+b*Log[c*x^n])^p/x,x] - e/d*Int[(a+b*Log[c*x^n])^p/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,0]

x:  ∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  when  p∈(SuperPlus[ℤ])

Rule: Integration by parts

Basis: (1/(x (d+e (x^r))))==(∂_x)((r Log[x]-Log[1+((e (x^r))/d)])/(d r))

Basis: (∂_x)(((a+b Log[c (x^n)]))^p)==((b n p (((a+b Log[c (x^n)]))^(p-1)))/x)

Note: This rule returns antiderivatives in terms of  (x^r) instead of  (x^(-r)), but requires more steps and larger antiderivatives.

Rule: If  p∈(SuperPlus[ℤ]), then

∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  ⟶  
(((r Log[x]-Log[1+((e (x^r))/d)]) (((a+b Log[c (x^n)]))^p))/(d r))-((b n p)/d)∫((Log[x] (((a+b Log[c (x^n)]))^(p-1)))/x)dx+((b n p)/(d r))∫((Log[1+((e (x^r))/d)] (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

(* Int[(a_.+b_.*Log[c_.*x_^n_.])^p_./(x_*(d_+e_.*x_^r_.)),x_Symbol] :=
  (r*Log[x]-Log[1+(e*x^r)/d])*(a+b*Log[c*x^n])^p/(d*r) - 
  b*n*p/d*Int[Log[x]*(a+b*Log[c*x^n])^(p-1)/x,x] + 
  b*n*p/(d*r)*Int[Log[1+(e*x^r)/d]*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[p,0] *)

3:  ∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  when  p∈(SuperPlus[ℤ])

Rule: Integration by parts

Basis: (1/(x (d+e (x^r))))==-(1/(d r)) (∂_x)Log[1+(d/(e (x^r)))]

Rule: If  p∈(SuperPlus[ℤ]), then

∫((((a+b Log[c (x^n)]))^p)/(x (d+e (x^r))))dx  ⟶  -((Log[1+(d/(e (x^r)))] (((a+b Log[c (x^n)]))^p))/(d r))+((b n p)/(d r))∫((Log[1+(d/(e (x^r)))] (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_./(x_*(d_+e_.*x_^r_.)),x_Symbol] :=
  -Log[1+d/(e*x^r)]*(a+b*Log[c*x^n])^p/(d*r) + 
  b*n*p/(d*r)*Int[Log[1+d/(e*x^r)]*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[p,0]

2.  ∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])

1:  ∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])∧ q>0

Rule: Algebraic expansion

Basis: ((((d+e x))^q)/x)==((d (((d+e x))^(q-1)))/x)+e (((d+e x))^(q-1))

Rule: If  p∈(SuperPlus[ℤ])∧ q>0, then

∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  d ∫(((((d+e x))^(q-1)) (((a+b Log[c (x^n)]))^p))/x)dx+e ∫(((d+e x))^(q-1)) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(d_+e_.*x_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  d*Int[(d+e*x)^(q-1)*(a+b*Log[c*x^n])^p/x,x] + 
  e*Int[(d+e*x)^(q-1)*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,0] && GtQ[q,0] && IntegerQ[2*q]

2:  ∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])∧ q<-1

Rule: Algebraic expansion

Basis: ((((d+e x))^q)/x)==((((d+e x))^(q+1))/(d x))-((e (((d+e x))^q))/d)

Rule: If  p∈(SuperPlus[ℤ])∧ q<-1, then

∫(((((d+e x))^q) (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  (1/d)∫(((((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^p))/x)dx-(e/d)∫(((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(d_+e_.*x_)^q_*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  1/d*Int[(d+e*x)^(q+1)*(a+b*Log[c*x^n])^p/x,x] - 
  e/d*Int[(d+e*x)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,0] && LtQ[q,-1] && IntegerQ[2*q]

3:  ∫(((((d+e (x^r)))^q) (a+b Log[c (x^n)]))/x) dx  when  q-(1/2)∈ℤ

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Rule: If  q-(1/2)∈ℤ, let u->∫((((d+e (x^r)))^q)/x) dx, then

∫(((((d+e (x^r)))^q) (a+b Log[c (x^n)]))/x)dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.])/x_,x_Symbol] :=
  With[{u=IntHide[(d+e*x^r)^q/x,x]},  
  u*(a+b*Log[c*x^n]) - b*n*Int[Dist[1/x,u,x],x]] /;
FreeQ[{a,b,c,d,e,n,r},x] && IntegerQ[q-1/2]

4:  ∫(((((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])∧ q+1∈(SuperMinus[ℤ])

Rule: Algebraic expansion

Basis: ((((d+e (x^r)))^q)/x)==((((d+e (x^r)))^(q+1))/(d x))-((e (x^(r-1)) (((d+e (x^r)))^q))/d)

Rule: If  p∈(SuperPlus[ℤ])∧ q+1∈(SuperMinus[ℤ]), then

∫(((((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  (1/d)∫(((((d+e (x^r)))^(q+1)) (((a+b Log[c (x^n)]))^p))/x)dx-(e/d)∫(x^(r-1)) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(d_+e_.*x_^r_.)^q_*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  1/d*Int[(d+e*x^r)^(q+1)*(a+b*Log[c*x^n])^p/x,x] - 
  e/d*Int[x^(r-1)*(d+e*x^r)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[p,0] && ILtQ[q,-1]

7:  ∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  m∈ℤ ∧ 2 q∈ℤ ∧ r∈ℤ

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Note: If  m∈ℤ ∧ q-(1/2)∈ℤ, then the terms of ∫(x^m) (((d+e x))^q)dx will be algebraic functions or constants times an inverse function.

Rule: If  m∈ℤ ∧ 2 q∈ℤ ∧ r∈ℤ, let u->∫(((f x))^m) (((d+e (x^r)))^q)dx, then

∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^r)^q,x]},  
  Dist[(a+b*Log[c*x^n]),u,x] - b*n*Int[SimplifyIntegrand[u/x,x],x] /;
 (EqQ[r,1] || EqQ[r,2]) && IntegerQ[m] && IntegerQ[q-1/2] || InverseFunctionFreeQ[u,x]] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && IntegerQ[2*q] && (IntegerQ[m] && IntegerQ[r] || IGtQ[q,0])

8:  ∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  q∈ℤ ∧ (q>0 ∨ m∈ℤ ∧ r∈ℤ)

Derivation: Algebraic expansion

Rule: If  q∈ℤ ∧ (q>0 ∨ m∈ℤ ∧ r∈ℤ), then

∫(((f x))^m) (((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  ∫(a+b Log[c (x^n)])ExpandIntegrand[(((f x))^m) (((d+e (x^r)))^q),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*Log[c*x^n]),(f*x)^m*(d+e*x^r)^q,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,m,n,q,r},x] && IntegerQ[q] && (GtQ[q,0] || IntegerQ[m] && IntegerQ[r])

9:  ∫(x^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  q∈ℤ ∧ (r/n)∈ℤ ∧ ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ p∈(SuperPlus[ℤ]))

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m) F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Rule: If q∈ℤ ∧ (r/n)∈ℤ ∧ ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ p∈(SuperPlus[ℤ])), then

∫(x^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((d+e (x^(r/n))))^q) (((a+b Log[c x]))^p)dx,x,(x^n)]

Program code:

Int[x_^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_])^p_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(d+e*x^(r/n))^q*(a+b*Log[c*x])^p,x],x,x^n] /;
FreeQ[{a,b,c,d,e,m,n,p,q,r},x] && IntegerQ[q] && IntegerQ[r/n] && IntegerQ[Simplify[(m+1)/n]] && (GtQ[(m+1)/n,0] || IGtQ[p,0])

10:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  q∈ℤ ∧ (q>0 ∨ p∈(SuperPlus[ℤ])∧ m∈ℤ ∧ r∈ℤ)

Derivation: Algebraic expansion

Rule: If  q∈ℤ ∧ (q>0 ∨ p∈(SuperPlus[ℤ])∧ m∈ℤ ∧ r∈ℤ), then

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((a+b Log[c (x^n)]))^p)ExpandIntegrand[(((f x))^m) (((d+e (x^r)))^q),x]dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*Log[c*x^n])^p,(f*x)^m*(d+e*x^r)^q,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q,r},x] && IntegerQ[q] && (GtQ[q,0] || IGtQ[p,0] && IntegerQ[m] && IntegerQ[r])

U:  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Rule:

∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(f_.*x_)^m_.*(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(d+e*x^r)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q,r},x]

N:  ∫(((f x))^m) (u^q) (((a+b Log[c (x^n)]))^p)dx  when  u==d+e (x^r)

Derivation: Algebraic normalization

Rule: If  u==d+e (x^r), then

∫(((f x))^m) (u^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((f x))^m) (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(f_.*x_)^m_.*u_^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Int[(f*x)^m*ExpandToSum[u,x]^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,f,m,n,p,q},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

5.  ∫AF[x](((a+b Log[c (x^n)]))^p)dx

1:  ∫Poly[x](((a+b Log[c (x^n)]))^p)dx

Derivation: Algebraic expansion

Rule:

∫Poly[x](((a+b Log[c (x^n)]))^p)dx  ⟶  ∫ExpandIntegrand[Poly[x](((a+b Log[c (x^n)]))^p),x]dx

Program code:

Int[Polyx_*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Int[ExpandIntegrand[Polyx*(a+b*Log[c*x^n])^p,x],x] /;
FreeQ[{a,b,c,n,p},x] && PolynomialQ[Polyx,x]

2:  ∫RF[x](((a+b Log[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule: If  p∈(SuperPlus[ℤ]), then

∫RF[x](((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((a+b Log[c (x^n)]))^p)ExpandIntegrand[RF[x],x]dx

Program code:

Int[RFx_*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*Log[c*x^n])^p,RFx,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,n},x] && RationalFunctionQ[RFx,x] && IGtQ[p,0]

Int[RFx_*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[RFx*(a+b*Log[c*x^n])^p,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,n},x] && RationalFunctionQ[RFx,x] && IGtQ[p,0]

U:  ∫AF[x] (((a+b Log[c (x^n)]))^p)dx

Rule:

∫AF[x] (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫AF[x] (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[AFx_*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[AFx*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,n,p},x] && AlgebraicFunctionQ[AFx,x,True]

6.  ∫(((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx

1:  ∫(((a+b Log[c (x^n)]))^p) (((d+e Log[c (x^n)]))^q)dx  when  p∈ℤ ∧ q∈ℤ

Derivation: Algebraic expansion

Rule: If  p∈ℤ ∧ q∈ℤ, then

∫(((a+b Log[c (x^n)]))^p) (((d+e Log[c (x^n)]))^q)dx  ⟶  ∫ExpandIntegrand[(((a+b Log[c (x^n)]))^p) (((d+e Log[c (x^n)]))^q),x]dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_.*(d_+e_.*Log[c_.*x_^n_.])^q_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*Log[c*x^n])^p*(d+e*Log[c*x^n])^q,x],x] /;
FreeQ[{a,b,c,d,e,n},x] && IntegerQ[p] && IntegerQ[q]

2:  ∫(((a+b Log[c (x^n)]))^p) (d+e Log[f (x^r)])dx

Derivation: Integration by parts

Rule: Let u->∫(((a+b Log[c (x^n)]))^p)dx, then

∫(((a+b Log[c (x^n)]))^p) (d+e Log[f (x^r)])dx  ⟶  u (d+e Log[f (x^r)])-e r ∫(u/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_.*(d_.+e_.*Log[f_.*x_^r_.]),x_Symbol] :=
  With[{u=IntHide[(a+b*Log[c*x^n])^p,x]},
  Dist[d+e*Log[f*x^r],u,x] - e*r*Int[SimplifyIntegrand[u/x,x],x]] /;
FreeQ[{a,b,c,d,e,f,n,p,r},x]

3:  ∫(((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx  when  p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ]), then

∫(((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx  ⟶  

x (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)-e q r ∫(((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^(q-1))dx-b n p ∫(((a+b Log[c (x^n)]))^(p-1)) (((d+e Log[f (x^r)]))^q)dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_.*(d_.+e_.*Log[f_.*x_^r_.])^q_.,x_Symbol] :=
  x*(a+b*Log[c*x^n])^p*(d+e*Log[f*x^r])^q - 
  e*q*r*Int[(a+b*Log[c*x^n])^p*(d+e*Log[f*x^r])^(q-1),x] - 
  b*n*p*Int[(a+b*Log[c*x^n])^(p-1)*(d+e*Log[f*x^r])^q,x] /;
FreeQ[{a,b,c,d,e,f,n,r},x] && IGtQ[p,0] && IGtQ[q,0]

U:  ∫(((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx

Rule:

∫(((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx  ⟶  ∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_.*(d_.+e_.*Log[f_.*x_^r_.])^q_.,x_Symbol] :=
  Unintegrable[(a+b*Log[c*x^n])^p*(d+e*Log[f*x^r])^q,x] /;
FreeQ[{a,b,c,d,e,f,n,p,q,r},x]

S:  ∫(((a+b Log[v]))^p) (((c+d Log[v]))^q)dx  when  v==g+h x ∧ g≠0

Derivation: Integration by substitution

Rule: If  v==g+h x ∧ g≠0, then

∫(((a+b Log[v]))^p) (((c+d Log[v]))^q)dx  ⟶  (1/h) Subst[∫(((a+b Log[x]))^p) (((c+d Log[x]))^q)dx,x,g+h x]

Program code:

Int[(a_.+b_.*Log[v_])^p_.*(c_.+d_.*Log[v_])^q_.,x_Symbol] :=
  1/Coeff[v,x,1]*Subst[Int[(a+b*Log[x])^p*(c+d*Log[x])^q,x],x,v] /;
FreeQ[{a,b,c,d,p,q},x] && LinearQ[v,x] && NeQ[Coeff[v,x,0],0]

7.  ∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx

1:  ∫(((((a+b Log[c (x^n)]))^p) (((d+e Log[c (x^n)]))^q))/x)dx

Derivation: Integration by substitution

Basis: ((F[Log[c (x^n)]])/x)==(1/n) Subst[F[x],x,Log[c (x^n)]] (∂_x)Log[c (x^n)]

Rule:

∫(((((a+b Log[c (x^n)]))^p) (((d+e Log[c (x^n)]))^q))/x)dx  ⟶  (1/n)Subst[∫(((a+b x))^p) (((d+e x))^q)dx,x,Log[c (x^n)]]

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_.*(d_.+e_.*Log[c_.*x_^n_.])^q_./x_,x_Symbol] :=
  1/n*Subst[Int[(a+b*x)^p*(d+e*x)^q,x],x,Log[c*x^n]] /;
FreeQ[{a,b,c,d,e,n,p,q},x]

2:  ∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (d+e Log[f (x^r)])dx

Derivation: Integration by parts

Rule: Let u->∫(((g x))^m) (((a+b Log[c (x^n)]))^p)dx, then

∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (d+e Log[f (x^r)])dx  ⟶  u (d+e Log[f (x^r)])-e r ∫(u/x)dx

Program code:

Int[(g_.*x_)^m_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.*(d_.+e_.*Log[f_.*x_^r_.]),x_Symbol] :=
  With[{u=IntHide[(g*x)^m*(a+b*Log[c*x^n])^p,x]},
  Dist[(d+e*Log[f*x^r]),u,x] - e*r*Int[SimplifyIntegrand[u/x,x],x]] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p,r},x] && Not[EqQ[p,1] && EqQ[a,0] && NeQ[d,0]]

3:  ∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx  when  p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])∧ m≠-1

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ q∈(SuperPlus[ℤ])∧ m≠-1, then

∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx  ⟶  

(((((g x))^(m+1)) (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q))/(g (m+1)))-((e q r)/(m+1))∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^(q-1))dx-((b n p)/(m+1)) ∫(((g x))^m) (((a+b Log[c (x^n)]))^(p-1)) (((d+e Log[f (x^r)]))^q)dx

Program code:

Int[(g_.*x_)^m_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.*(d_.+e_.*Log[f_.*x_^r_.])^q_.,x_Symbol] :=
  (g*x)^(m+1)*(a+b*Log[c*x^n])^p*(d+e*Log[f*x^r])^q/(g*(m+1)) - 
  e*q*r/(m+1)*Int[(g*x)^m*(a+b*Log[c*x^n])^p*(d+e*Log[f*x^r])^(q-1),x] - 
  b*n*p/(m+1)*Int[(g*x)^m*(a+b*Log[c*x^n])^(p-1)*(d+e*Log[f*x^r])^q,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,r},x] && IGtQ[p,0] && IGtQ[q,0] && NeQ[m,-1]

U:  ∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx

Rule:

∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx  ⟶  ∫(((g x))^m) (((a+b Log[c (x^n)]))^p) (((d+e Log[f (x^r)]))^q)dx

Program code:

Int[(g_.*x_)^m_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.*(d_.+e_.*Log[f_.*x_^r_.])^q_.,x_Symbol] :=
  Unintegrable[(g*x)^m*(a+b*Log[c*x^n])^p*(d+e*Log[f*x^r])^q,x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p,q,r},x]

S:  ∫(u^m) (((a+b Log[v]))^p) (((c+d Log[v]))^q)dx  when  u==e+f x ∧ v==g+h x ∧ f g-e h==0 ∧ g≠0

Derivation: Integration by substitution

Rule: If  u==e+f x ∧ v==g+h x ∧ f g-e h==0 ∧ g≠0, then

∫(u^m) (((a+b Log[v]))^p) (((c+d Log[v]))^q)dx  ⟶  (1/h) Subst[∫(((((f x)/h)))^m) (((a+b Log[x]))^p) (((c+d Log[x]))^q)dx,x,g+h x]

Program code:

Int[u_^m_.*(a_.+b_.*Log[v_])^p_.*(c_.+d_.*Log[v_])^q_.,x_Symbol] :=
  With[{e=Coeff[u,x,0],f=Coeff[u,x,1],g=Coeff[v,x,0],h=Coeff[v,x,1]},
  1/h*Subst[Int[(f*x/h)^m*(a+b*Log[x])^p*(c+d*Log[x])^q,x],x,v] /;
 EqQ[f*g-e*h,0] && NeQ[g,0]] /;
FreeQ[{a,b,c,d,m,p,q},x] && LinearQ[{u,v},x]

8.  ∫Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx

1:  ∫Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])∧ m∈ℝ ∧ (p==1 ∨ (1/m)∈ℤ ∨ r==1 ∧ m==1 ∧ d e==1)

Derivation: Integration by parts

Note: If  m∈ℝ, then ((∫Log[d (((e+f (x^m)))^r)]dx)/x) is integrable.

Rule: If  p∈(SuperPlus[ℤ])∧ m∈ℝ ∧ (p==1 ∨ (1/m)∈ℤ ∨ r==1 ∧ m==1 ∧ d e==1), let u->∫Log[d (((e+f (x^m)))^r)]dx, then

∫Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx  ⟶  u (((a+b Log[c (x^n)]))^p)-b n p ∫((u (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[Log[d_.*(e_+f_.*x_^m_.)^r_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  With[{u=IntHide[Log[d*(e+f*x^m)^r],x]},
  Dist[(a+b*Log[c*x^n])^p,u,x] - b*n*p*Int[Dist[(a+b*Log[c*x^n])^(p-1)/x,u,x],x]] /;
FreeQ[{a,b,c,d,e,f,r,m,n},x] && IGtQ[p,0] && RationalQ[m] && (EqQ[p,1] || FractionQ[m] && IntegerQ[1/m] || EqQ[r,1] && EqQ[m,1] && EqQ[d*e,1])

2:  ∫Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])∧ m∈ℤ

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ m∈ℤ, let u->∫(((a+b Log[c (x^n)]))^p)dx, then

∫Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx  ⟶  u Log[d (((e+f (x^m)))^r)]-f m r ∫((u (x^(m-1)))/(e+f (x^m)))dx

Program code:

Int[Log[d_.*(e_+f_.*x_^m_.)^r_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  With[{u=IntHide[(a+b*Log[c*x^n])^p,x]},
  Dist[Log[d*(e+f*x^m)^r],u,x] - f*m*r*Int[Dist[x^(m-1)/(e+f*x^m),u,x],x]] /;
FreeQ[{a,b,c,d,e,f,r,m,n},x] && IGtQ[p,0] && IntegerQ[m]

U:  ∫Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx

Rule:

∫Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[Log[d_.*(e_+f_.*x_^m_.)^r_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[Log[d*(e+f*x^m)^r]*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,r,m,n,p},x]

N:  ∫Log[d (u^r)] (((a+b Log[c (x^n)]))^p)dx  when  u==e+f (x^m)

Derivation: Algebraic normalization

Rule: If  u==e+f (x^m), then

∫(((g x))^q) Log[d (u^r)] (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[Log[d_.*u_^r_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Int[Log[d*ExpandToSum[u,x]^r]*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,r,n,p},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

9.  ∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx

1.  ∫((Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])

1:  ∫((Log[d (e+f (x^m))] (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])∧ d e==1

Derivation: Integration by parts

Basis: If  d e==1, then ((Log[d (e+f (x^m))])/x)==-(∂_x)((PolyLog[2,-d f (x^m)])/m)

Rule: If  p∈(SuperPlus[ℤ])∧ d e==1, then

∫((Log[d (e+f (x^m))] (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  -((PolyLog[2,-d f (x^m)] (((a+b Log[c (x^n)]))^p))/m)+((b n p)/m) ∫((PolyLog[2,-d f (x^m)] (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[Log[d_.*(e_+f_.*x_^m_.)]*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  -PolyLog[2,-d*f*x^m]*(a+b*Log[c*x^n])^p/m + 
  b*n*p/m*Int[PolyLog[2,-d*f*x^m]*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,f,m,n},x] && IGtQ[p,0] && EqQ[d*e,1]

2:  ∫((Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p))/x)dx  when  p∈(SuperPlus[ℤ])∧ d e≠1

Derivation: Integration by parts

Basis: ((((a+b Log[c (x^n)]))^p)/x)==(∂_x)((((a+b Log[c (x^n)]))^(p+1))/(b n (p+1)))

Basis: (∂_x)Log[d (((e+f (x^m)))^r)]==((f m r (x^(m-1)))/(e+f (x^m)))

Rule: If  p∈(SuperPlus[ℤ])∧ d e≠1, then

∫((Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  ((Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^(p+1)))/(b n (p+1)))-((f m r)/(b n (p+1)))∫(((x^(m-1)) (((a+b Log[c (x^n)]))^(p+1)))/(e+f (x^m))) dx

Program code:

Int[Log[d_.*(e_+f_.*x_^m_.)^r_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  Log[d*(e+f*x^m)^r]*(a+b*Log[c*x^n])^(p+1)/(b*n*(p+1)) - 
  f*m*r/(b*n*(p+1))*Int[x^(m-1)*(a+b*Log[c*x^n])^(p+1)/(e+f*x^m),x] /;
FreeQ[{a,b,c,d,e,f,r,m,n},x] && IGtQ[p,0] && NeQ[d*e,1]

2:  ∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (a+b Log[c (x^n)])dx  when  (((q+1)/m)∈ℤ  ∨ (m|q)∈ℝ) ∧ q≠-1

Derivation: Integration by parts

Note: If  ((q+1)/m)∈ℤ  ∨ (m|q)∈ℝ, then ((∫(((g x))^q) Log[d (((e+f (x^m)))^r)]dx)/x) is integrable.

Rule: If  (((q+1)/m)∈ℤ  ∨ (m|q)∈ℝ) ∧ q≠-1, let u->∫(((g x))^q) Log[d (((e+f (x^m)))^r)]dx, then

∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[(g_.*x_)^q_.*Log[d_.*(e_+f_.*x_^m_.)^r_.]*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[(g*x)^q*Log[d*(e+f*x^m)^r],x]},
  Dist[(a+b*Log[c*x^n]),u,x] - b*n*Int[Dist[1/x,u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g,r,m,n,q},x] && (IntegerQ[(q+1)/m] || RationalQ[m] && RationalQ[q]) && NeQ[q,-1]

3:  ∫(((g x))^q) Log[d (e+f (x^m))] (((a+b Log[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])∧ m∈ℝ ∧ q∈ℝ ∧ q≠-1 ∧ (p==1 ∨ ((q+1)/m)∈ℤ ∨ (q∈(SuperPlus[ℤ])∧ ((q+1)/m)∈ℤ ∧ d e==1))

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ m∈ℝ ∧ q∈ℝ ∧ q≠-1 ∧ (p==1 ∨ ((q+1)/m)∈ℤ ∨ (q∈(SuperPlus[ℤ])∧ ((q+1)/m)∈ℤ ∧ d e==1)), let u->∫(((g x))^q) Log[d (e+f (x^m))]dx, then

∫(((g x))^q) Log[d (e+f (x^m))] (((a+b Log[c (x^n)]))^p)dx  ⟶  u (((a+b Log[c (x^n)]))^p)-b n p ∫((u (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(g_.*x_)^q_.*Log[d_.*(e_+f_.*x_^m_.)]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  With[{u=IntHide[(g*x)^q*Log[d*(e+f*x^m)],x]},
  Dist[(a+b*Log[c*x^n])^p,u,x] - b*n*p*Int[Dist[(a+b*Log[c*x^n])^(p-1)/x,u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g,m,n,q},x] && IGtQ[p,0] && RationalQ[m] && RationalQ[q] && NeQ[q,-1] && 
  (EqQ[p,1] || FractionQ[m] && IntegerQ[(q+1)/m] || IGtQ[q,0] && IntegerQ[(q+1)/m] && EqQ[d*e,1])

4:  ∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx  when  p∈(SuperPlus[ℤ])∧ m∈ℝ ∧ q∈ℝ

Derivation: Integration by parts

Rule: If  p∈(SuperPlus[ℤ])∧ m∈ℝ ∧ q∈ℝ, let u->∫(((g x))^q) (((a+b Log[c (x^n)]))^p)dx, then

∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx  ⟶  u Log[d (((e+f (x^m)))^r)]-f m r ∫((u (x^(m-1)))/(e+f (x^m)))dx

Program code:

Int[(g_.*x_)^q_.*Log[d_.*(e_+f_.*x_^m_.)^r_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  With[{u=IntHide[(g*x)^q*(a+b*Log[c*x^n])^p,x]},
  Dist[Log[d*(e+f*x^m)^r],u,x] - f*m*r*Int[Dist[x^(m-1)/(e+f*x^m),u,x],x]] /;
FreeQ[{a,b,c,d,e,f,g,r,m,n,q},x] && IGtQ[p,0] && RationalQ[m] && RationalQ[q]

U:  ∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx

Rule:

∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(g_.*x_)^q_.*Log[d_.*(e_+f_.*x_^m_.)^r_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[(g*x)^q*Log[d*(e+f*x^m)^r]*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,f,g,r,m,n,p,q},x]

N:  ∫(((g x))^q) Log[d (u^r)] (((a+b Log[c (x^n)]))^p)dx  when  u==e+f (x^m)

Derivation: Algebraic normalization

Rule: If  u==e+f (x^m), then

∫(((g x))^q) Log[d (u^r)] (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((g x))^q) Log[d (((e+f (x^m)))^r)] (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(g_.*x_)^q_.*Log[d_.*u_^r_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Int[(g*x)^q*Log[d*ExpandToSum[u,x]^r]*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,g,r,n,p,q},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]

10.  ∫PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p)dx

1:  ∫PolyLog[k,e (x^q)] (a+b Log[c (x^n)])dx  when  k∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (a+b Log[c (x^n)])==(∂_x)(-b n x+x (a+b Log[c (x^n)]))

Basis: (∂_x)PolyLog[k,e (x^q)]==((q PolyLog[k-1,e (x^q)])/x)

Rule: If  k∈(SuperPlus[ℤ]), then

∫PolyLog[k,e (x^q)] (a+b Log[c (x^n)])dx  ⟶  

-b n x PolyLog[k,e (x^q)]+x PolyLog[k,e (x^q)] (a+b Log[c (x^n)])+
b n q ∫PolyLog[k-1,e (x^q)]dx-q ∫PolyLog[k-1,e (x^q)] (a+b Log[c (x^n)])dx

Program code:

Int[PolyLog[k_,e_.*x_^q_.]*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  -b*n*x*PolyLog[k,e*x^q] + x*PolyLog[k,e*x^q]*(a+b*Log[c*x^n]) + 
  b*n*q*Int[PolyLog[k-1,e*x^q],x] - q*Int[PolyLog[k-1,e*x^q]*(a+b*Log[c*x^n]),x] /;
FreeQ[{a,b,c,e,n,q},x] && IGtQ[k,0]

U:  ∫PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p)dx

Rule:

∫PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[PolyLog[k_,e_.*x_^q_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[PolyLog[k,e*x^q]*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,e,n,p,q},x]

11.  ∫(((d x))^m) PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p)dx

1.  ∫((PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p))/x)dx

1:  ∫((PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p))/x)dx  when  p>0

Derivation: Integration by parts

Basis: ((PolyLog[k,e (x^q)])/x)==(∂_x)((PolyLog[k+1,e (x^q)])/q)

Rule: If  p>0, then

∫((PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  
((PolyLog[k+1,e (x^q)] (((a+b Log[c (x^n)]))^p))/q)-((b n p)/q) ∫((PolyLog[k+1,e (x^q)] (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[PolyLog[k_,e_.*x_^q_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  PolyLog[k+1,e*x^q]*(a+b*Log[c*x^n])^p/q - b*n*p/q*Int[PolyLog[k+1,e*x^q]*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,e,k,n,q},x] && GtQ[p,0]

2:  ∫((PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p))/x)dx  when  p<-1

Derivation: Integration by parts

Basis: ((((a+b Log[c (x^n)]))^p)/x)==(∂_x)(( (((a+b Log[c (x^n)]))^(p+1)))/(b n (p+1)))

Basis: (∂_x)PolyLog[k,e (x^q)]==((q PolyLog[k-1,e (x^q)])/x)

Rule: If  p<-1, then

∫((PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p))/x)dx  ⟶  
((PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^(p+1)))/(b n (p+1)))-(q/(b n (p+1))) ∫((PolyLog[k-1,e (x^q)] (((a+b Log[c (x^n)]))^(p+1)))/x)dx

Program code:

Int[PolyLog[k_,e_.*x_^q_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_./x_,x_Symbol] :=
  PolyLog[k,e*x^q]*(a+b*Log[c*x^n])^(p+1)/(b*n*(p+1)) - q/(b*n*(p+1))*Int[PolyLog[k-1,e*x^q]*(a+b*Log[c*x^n])^(p+1)/x,x] /;
FreeQ[{a,b,c,e,k,n,q},x] && LtQ[p,-1]

2:  ∫(((d x))^m) PolyLog[k,e (x^q)] (a+b Log[c (x^n)])dx  when  k∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (((d x))^m) (a+b Log[c (x^n)])==(∂_x)(-((b n (((d x))^(m+1)))/(d (((m+1))^2)))+(((((d x))^(m+1)) (a+b Log[c (x^n)]))/(d (m+1))))

Basis: (∂_x)PolyLog[k,e (x^q)]==((q PolyLog[k-1,e (x^q)])/x)

Rule: If  k∈(SuperPlus[ℤ]), then

∫(((d x))^m) PolyLog[k,e (x^q)] (a+b Log[c (x^n)])dx  ⟶  

-((b n (((d x))^(m+1)) PolyLog[k,e (x^q)])/(d (((m+1))^2)))+(((((d x))^(m+1)) PolyLog[k,e (x^q)] (a+b Log[c (x^n)]))/(d (m+1)))+
((b n q)/( (((m+1))^2))) ∫(((d x))^m) PolyLog[k-1,e (x^q)]dx-(q/( (m+1))) ∫(((d x))^m) PolyLog[k-1,e (x^q)] (a+b Log[c (x^n)])dx

Program code:

Int[(d_.*x_)^m_.*PolyLog[k_,e_.*x_^q_.]*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  -b*n*(d*x)^(m+1)*PolyLog[k,e*x^q]/(d*(m+1)^2) + 
  (d*x)^(m+1)*PolyLog[k,e*x^q]*(a+b*Log[c*x^n])/(d*(m+1)) + 
  b*n*q/(m+1)^2*Int[(d*x)^m*PolyLog[k-1,e*x^q],x] - 
  q/(m+1)*Int[(d*x)^m*PolyLog[k-1,e*x^q]*(a+b*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d,e,m,n,q},x] && IGtQ[k,0]

U:  ∫(((d x))^m) PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p)dx

Rule:

∫(((d x))^m) PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((d x))^m) PolyLog[k,e (x^q)] (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(d_.*x_)^m_.*PolyLog[k_,e_.*x_^q_.]*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[(d*x)^m*PolyLog[k,e*x^q]*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x]

12.  ∫(Subscript[P, x])((F[d (e+f x)])^m) (a+b Log[c (x^n)])dx

1:  ∫(Subscript[P, x])((F[d (e+f x)])^m) (a+b Log[c (x^n)])dx  when  m∈(SuperPlus[ℤ])∧ F∈{ArcSin,ArcCos,ArcSinh, ArcCosh}

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Note: If  m∈(SuperPlus[ℤ])∧ F∈{ArcSin,ArcCos,ArcSinh, ArcCosh}, the terms of the antiderivative of ((∫(Subscript[P, x]) ((F[d (e+f x)])^m)dx)/x) will be integrable.

Rule: If  m∈(SuperPlus[ℤ])∧ F∈{ArcSin,ArcCos,ArcSinh, ArcCosh}, let u->∫(Subscript[P, x])((F[d (e+f x)])^m)dx, then

∫(Subscript[P, x])((F[d (e+f x)])^m) (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n∫(u/x)dx

Program code:

Int[Px_.*F_[d_.*(e_.+f_.*x_)]^m_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[Px*F[d*(e+f*x)]^m,x]},
  Dist[(a+b*Log[c*x^n]),u,x] - b*n*Int[Dist[1/x,u,x],x]] /;
FreeQ[{a,b,c,d,e,f,n},x] && PolynomialQ[Px,x] && IGtQ[m,0] && MemberQ[{ArcSin, ArcCos, ArcSinh, ArcCosh},F]

2:  ∫(Subscript[P, x])F[d (e+f x)] (a+b Log[c (x^n)])dx  when  F∈{ArcTan,ArcCot,ArcTanh, ArcCoth}

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Note: If  F∈{ArcTan,ArcCot,ArcTanh, ArcCoth}, the terms of the antiderivative of ((∫(Subscript[P, x]) F[d (e+f x)]dx)/x) will be integrable.

Rule: If  F∈{ArcTan,ArcCot,ArcTanh, ArcCoth}, let u->∫(Subscript[P, x])F[d (e+f x)]dx, then

∫(Subscript[P, x])F[d (e+f x)] (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n∫(u/x)dx

Program code:

Int[Px_.*F_[d_.*(e_.+f_.*x_)]*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[Px*F[d*(e+f*x)],x]},
  Dist[(a+b*Log[c*x^n]),u,x] - b*n*Int[Dist[1/x,u,x],x]] /;
FreeQ[{a,b,c,d,e,f,n},x] && PolynomialQ[Px,x] && MemberQ[{ArcTan, ArcCot, ArcTanh, ArcCoth},F]